Переходник D-вала шагового двигателя на ось Lego
Я работаю над prototype, и мне нужен переходник от вала двигателя к оси Lego для использования с шаговым двигателем.
Мой общий проект включает в себя управление шаговым двигателем с помощью C# через USB-соединение, чтобы совершать очень маленькие вращения, которые будут регулировать высоту предметного столика (сконструированного из Lego) для стереомикроскопа.
Мне нужны адаптеры, аналогичные адаптер оси D 6 мм для оси Lego Бесплатная модель для 3D-печати, но для вала D двигателя диаметром 4 мм и вала D двигателя диаметром 5 мм
Адаптер предназначен для очень малых и медленных вращений.
Я не хочу владеть макетами моделей, в идеале их можно раздавать бесплатно (аналогично ссылке выше).
Мне нужно несколько переходников; Напечатано по 3 штуки каждого (4 мм и 5 мм) и какова будет справедливая цена за это?
Я понятия не имею, какой тип материала следует использовать для их печати, я думаю, подойдет акрилонитрил-бутадиен-стирол (АБС).
@Gary Kindel, 👍2
Обсуждение1 ответ
Лучший ответ:
OpenSCAD хорошо подходит для создания чего-либо, состоящего из относительно простых фигур, где для некоторых частей фигур требуются разные размеры, например диаметры и смещения валов шагового двигателя.
Решение в OpenSCAD может выглядеть примерно так:
outer_diameter = 8.5; //Внешний диаметр переходника
stepper_length = 12; //Длина шагового вала
stepper_diameter = 4; //Диаметр шагового вала
stepper_d_offset = 1.6; //Смещение от центра вала к плоскости D
// вал 4 мм: d = 4, смещение = 1,6
//вал 5 мм: d = 5, смещение = 2
// вал 6 мм: d = 6, смещение = 2,5
thickness_mid = 2; //Толщина массивного сечения между валами степпера и лего
lego_length = 10; //Длина лего вала
lego_diameter = 4.9; //Внешний диаметр вала лего
lego_internal_width = 1.9; //Ширина пазов под вал
lego_corner_radius = 0.5;
cutout_size = lego_diameter;
cutout_translate = cutout_size / 2 + lego_internal_width / 2;
$fn = 128; //Точность/разрешение кругов
eps = 0.01;
module fillet_square(width, radius) {
translate([radius - width / 2, radius - width / 2, 0])
minkowski() {
square(width - 2 * radius);
circle(radius);
}
}
color(0,0.5)
union(){
linear_extrude(height = stepper_length + eps) {
difference() {
circle(d = outer_diameter);
difference() {
circle(d = stepper_diameter);
translate([0, stepper_d_offset + stepper_diameter / 2, 0]) {
square(size = stepper_diameter, center = true);
}
}
}
}
translate([0, 0, stepper_length]) {
linear_extrude(height = thickness_mid) {
circle(d = outer_diameter);
}
}
translate([0, 0, stepper_length + thickness_mid - eps]) {
linear_extrude(height = lego_length + eps) {
difference() {
circle(d = outer_diameter);
difference() {
circle(d = lego_diameter);
translate([cutout_translate, cutout_translate, 0]) {
fillet_square(cutout_size, lego_corner_radius);
}
translate([cutout_translate, -cutout_translate, 0]) {
fillet_square(cutout_size, lego_corner_radius);
}
translate([-cutout_translate, cutout_translate, 0]) {
fillet_square(cutout_size, lego_corner_radius);
}
translate([-cutout_translate, -cutout_translate, 0]) {
fillet_square(cutout_size, lego_corner_radius);
}
}
}
}
}
}
Затем вы можете экспортировать файл .stl (или любой другой формат) для 3D-печати из OpenSCAD.
Отличный ответ, я бы рассмотрел больший внешний диаметр для увеличения несущей способности (крутящего момента). Возможно, упоминание о том, что вы не должны печатать это вертикальное положение, может быть полезным., @0scar
Спасибо за решение. Установил OpenSCAD и вставил в свой код часть, отрисованную без проблем!, @Gary Kindel
- Каков самый простой способ изменить/изменить размер объекта внутри STL-файла?
- Будут ли 3D напечатные игральные кости честными?
- Действительно ли 3D-принтеры достигают точности 50 микрон (0,05 мм)?
- Файл слишком большой, чтобы открыть его в Tinkercad. Как уменьшить его?
- Являются ли самопересекающиеся сетки грязными с точки зрения 3D-печати?
- Как вычислить поверхность и объем большого количества файлов STL?
- Моя 3D-модель печатает с недостающими частями при нарезке в Ultimaker Cura
- Шрифт для резки?
Это похоже на хорошее упражнение для начинающих САПР. б) 50 часов в час на разработку, 5 часов в час на печать — это то, что я обычно использую. c) ABS, ASA, HIPS или, если возможно, нейлон. d) Артиллерийский шершень, хотя предложения по покупке выходят за рамки этой SE., @towe